Section courante

A propos

Section administrative du site

Dans les pays occidentaux, il est inévitable de calculer la date de la Pâque chrétienne. Vous trouverez la réponse que vous souhaitez, à l'aide du code source Quick Basic/QBasic suivant :

  1. DECLARE SUB DateOfEaster (year AS INTEGER, month AS INTEGER, day AS INTEGER)
  2. DECLARE FUNCTION MonthName$ (month AS INTEGER)
  3.     
  4.  
  5. FOR year% = 2000 TO 2014
  6.     CALL DateOfEaster(year%, month%, day%)
  7.     PRINT "Pâque en l'année " + STR$(year%) + " est le jour " + STR$(day%) + " du mois " + MonthName$(month%)
  8. NEXT
  9.  
  10. SUB DateOfEaster (year AS INTEGER, month AS INTEGER, day AS INTEGER)
  11.         g% = (year MOD 19) + 1
  12.         c% = INT(year / 100) + 1
  13.         x% = INT((3 * c%) / 4) - 12
  14.         z% = INT((8 * c% + 5) / 25) - 5
  15.         d% = INT((5 * year) / 4) - x% - 10
  16.         e% = INT(11 * g% + 20 + z% - x%) MOD 30
  17.         IF e% < 0 THEN e% = e% + 30
  18.         IF ((e% = 25) AND (g% > 11)) OR (e% = 24) THEN e% = e% + 1
  19.         n% = 44 - e%
  20.         IF n% < 21 THEN n% = n% + 30
  21.         n% = n% + 7 - INT((d% + n%) MOD 7)
  22.         IF n% > 31 THEN
  23.            month = 4
  24.            day = n% - 31
  25.         ELSE
  26.            month = 3
  27.            day = n%
  28.         END IF
  29. END SUB
  30.  
  31. FUNCTION MonthName$ (month AS INTEGER)
  32.    SELECT CASE month
  33.     CASE 1: MonthName$ = "Janvier"
  34.     CASE 2: MonthName$ = "Février"
  35.     CASE 3: MonthName$ = "Mars"
  36.     CASE 4: MonthName$ = "Avril"
  37.     CASE 5: MonthName$ = "Mai"
  38.     CASE 6: MonthName$ = "Juin"
  39.     CASE 7: MonthName$ = "Juillet"
  40.     CASE 8: MonthName$ = "Août"
  41.     CASE 9: MonthName$ = "Septembre"
  42.     CASE 10: MonthName$ = "Octobre"
  43.     CASE 11: MonthName$ = "Novembre"
  44.     CASE 12: MonthName$ = "Décembre"
  45.    END SELECT
  46. END FUNCTION

on obtiendra le résultat suivant :

Pâque en l'année 2000 est le jour 23 du mois Avril
Pâque en l'année 2001 est le jour 15 du mois Avril
Pâque en l'année 2002 est le jour 31 du mois Mars
Pâque en l'année 2003 est le jour 20 du mois Avril
Pâque en l'année 2004 est le jour 11 du mois Avril
Pâque en l'année 2005 est le jour 27 du mois Mars
Pâque en l'année 2006 est le jour 16 du mois Avril
Pâque en l'année 2007 est le jour 8 du mois Avril
Pâque en l'année 2008 est le jour 23 du mois Mars
Pâque en l'année 2009 est le jour 12 du mois Avril
Pâque en l'année 2010 est le jour 4 du mois Avril
Pâque en l'année 2011 est le jour 24 du mois Avril
Pâque en l'année 2012 est le jour 8 du mois Avril
Pâque en l'année 2013 est le jour 31 du mois Mars
Pâque en l'année 2014 est le jour 20 du mois Avril


Dernière mise à jour : Mercredi, le 14 septembre 2016