Section courante

A propos

Section administrative du site

Il est très agaçant d'avoir des formules toutes préparés d'avance fonctionnant très bien dans des tableurs et ne pas être capable d'effectuer les mêmes calculs et les mêmes réponses dans une situation anodine de la programmation. Une de ces remarquables fonctions, est celle du Lotus 1-2-3 et de Quattro Pro, elle se nomme la fonction PPaymt en anglais ou Principal en français. A l'aide du code source Quick Basic/QBasic suivant, vous trouverez la réponse que vous souhaitez :

  1. DECLARE FUNCTION FVal! (rate!, nPer!, pmt!, pV!, pType!)
  2. DECLARE FUNCTION Paymt! (rate!, nPer!, pV!, fV!, pType!)
  3. DECLARE FUNCTION PPaymt! (rate!, per!, nPer!, pV!, fV!, pType!)
  4.  
  5. PRINT "Exemple de versements trimestriels d'un prêt de 10 000$ à 15% par trimestre:"
  6. PRINT STR$(PPaymt(.15 / 4, 24, 40, 10000, 0, 1)) + "$"
  7. PRINT "Exemple de versements d'un prêt de 100 000$ à 10% par mois:"
  8. PRINT STR$(PPaymt(.1 / 12, 2 * 12, 30 * 12, 100000, 0, 0)) + "$"
  9.  
  10. FUNCTION FVal (rate, nPer, pmt, pV, pType)
  11.  f = EXP(nPer * LOG(1! + rate))
  12.  IF ABS(rate) < .000001 THEN
  13.     FVal = -pmt * nPer * (1! + (nPer - 1!) * rate / 2!) * (1! + rate * pType) - pV * f
  14.  ELSE
  15.     FVal = pmt * (1 - f) * (1 / rate + pType) - pV * f
  16.  END IF
  17. END FUNCTION
  18.  
  19. FUNCTION Paymt (rate, nPer, pV, fV, pType)
  20.  f = EXP(nPer * LOG(1! + rate))
  21.  Paymt = (fV + pV * f) * rate / ((1 + rate * pType) * (1! - f))
  22. END FUNCTION
  23.  
  24. FUNCTION PPaymt (rate, per, nPer, pV, fV, pType)
  25.     f = Paymt(rate, nPer, pV, fV, pType)
  26.     PPaymt = f - rate * FVal(rate, per - pType - 1, f, pV, pType)
  27. END FUNCTION

on obtiendra le résultat suivant :

Exemple de versements trimestriels d'un prêt de 10 000$ à 15% par trimestre:
-233.243
Exemple de versements d'un prêt de 100 000$ à 10% par mois:
-53.542


Dernière mise à jour : Mercredi, le 14 septembre 2016