Section courante

A propos

Section administrative du site

Introduction

Une des connaissances oublier de tous, c'est que certains modèles de clone de XT ont déjà supporté différents CMOS de fabricant tiers. Afin de facilité la compréhension du problème j'ai retiré certaines partie du code source de démarrage de la bibliothèque du Malte Genesis V: Alias Adèle du progiciel du MonsterBook dont voici pour le plus grand bénéfice de tous l'extrait du source :

  1. ; ---------------------------------------------------------------------------------------------------------------------------------------------------------------------
  2. ; Extrait du système de démarrage du progiciel MonsterBook
  3. ; Tous droits réservés par les Gladir.com
  4. ; Developpeur: Sylvain Maltais (smaltais@gladir.com)
  5. ;
  6. ; Utilisation à titre éducatif ou communautaire seulement
  7. ; --------------------------------------------------------------------------------------------------------------------------------------------------------------------- 
  8.  
  9. ;Drapeau d'existance des Interruptions de la variable IntExistFlag
  10.  flgInt10h equ 1     ; Drapeau indiquant l'existance de l'interruption 10h
  11.  flgInt11h equ 2     ; Drapeau indiquant l'existance de l'interruption 11h
  12.  flgInt12h equ 4     ; Drapeau indiquant l'existance de l'interruption 12h
  13.  flgInt13h equ 8     ; Drapeau indiquant l'existance de l'interruption 13h
  14.  flgInt14h equ 0010h ; Drapeau indiquant l'existance de l'interruption 14h
  15.  flgInt15h equ 0020h ; Drapeau indiquant l'existance de l'interruption 15h
  16.  flgInt16h equ 0040h ; Drapeau indiquant l'existance de l'interruption 16h
  17.  flgInt1Ah equ 0080h ; Drapeau indiquant l'existance de l'interruption 1Ah
  18.  flgInt21h equ 0100h ; Drapeau indiquant l'existance de l'interruption 21h
  19.  flgInt2Ah equ 0200h ; Drapeau indiquant l'existance de l'interruption 2Ah
  20.  flgInt2Fh equ 0400h ; Drapeau indiquant l'existance de l'interruption 2Fh
  21.  flgInt33h equ 0800h ; Drapeau indiquant l'existance de l'interruption 33h
  22.  flgInt67h equ 1000h ; Drapeau indiquant l'existance de l'interruption 67h
  23.  
  24. ; ---------------------------------------------------------------------------------------------------------------------------------------------------------------------
  25. ;                       Structure des cavaliers du démarrage
  26. ; ---------------------------------------------------------------------------------------------------------------------------------------------------------------------
  27.  
  28. Jumper STRUC
  29.  FlgMethod DW ?
  30. ENDS
  31.  
  32. ; ---------------------------------------------------------------------------------------------------------------------------------------------------------------------
  33. ;                              Structure de démarrage
  34. ; ---------------------------------------------------------------------------------------------------------------------------------------------------------------------
  35.  
  36. StartUpRec STRUC
  37.  ; Info sur le Micro-Processeur et son bus système
  38.  CPU           DB ? ; Modèle de CPU
  39.  Up32Bits      DB ? ; Boolean: Support les instructions 32 bits?
  40.  CPUIDSupport  DB ? ; Boolean: Support l'instruction CPUID?
  41.  CPUVendor     DB ? ; Byte: Fabricant du CPU?
  42.  Bus           DB ? ; Taille du Bus de données
  43.  ; Info sur le modèle d'Ordinateur
  44.  ComputerName  DW ?
  45.  PS2           DB ? ; Est-ce un PS/2 d'IBM?
  46.  ; Info sur les Interruptions
  47.  IntExistFlags DW ?
  48.  ;Information sur le DOS
  49.  GetDosVer     DW ?
  50.  GetDosBlock   DD ? ; DosBlockPtr
  51.  HandleExist   DB ? ; Boolean: Est-ce que les Handles existent?
  52.  ;Information sur OS/2 et Windows
  53.  OS2           DB ? ; Boolean
  54.  OS2HiVer      DB ? ; Version OS/2
  55.  OS2LoVer      DB ? ; Sous-version OS/2
  56.  Win           DB ? ; Mode de fonctionnement de Windows
  57.  WinLoVer      DB ? ; Sous-version Windows
  58.  WinHiVer      DB ? ; Version Windows
  59.  ;Information de pays
  60.  CountryCode   DW ?
  61.  CodePage      DW ?
  62.  Date          DW ?        ; Format de la date
  63.  Curr          DB 5 DUP(?) ; Array[0..4]of Chr
  64.  ThSep         DW ?        ; Array[0..1]of Chr
  65.  DeSep         DW ?        ; Array[0..1]of Chr
  66.  DtSep         DW ?        ; Array[0..1]of Chr
  67.  TmSep         DW ?        ; Array[0..1]of Chr
  68.  CurrStyle     DB ?
  69.  Digits        DB ?
  70.  Time          DB ?        ; TimeType
  71.  CaseUp        DD ?        ; Pointer
  72.  DaSep         DW ?        ; Array[0..1]of Chr
  73.  ;Information sur le(s) lecteur(s) de disquette
  74.  FloppyDskExist DB ? ; Boolean
  75.  NmFloppyDsk    DB ?
  76.  ;Info sur le(s) disque(s) dur
  77.  HardDskExist   DB ? ; Boolean
  78.  NmHardDsk      DB ?
  79.  HardDskCtrl    DW ? ; Modèle de contrôleur de disque dur
  80.   ; Information réseau
  81.  IsNovell       DB ? ; Boolean: Réseau Novell présent
  82.  ; Spooler d'imprimante
  83.  Spooler        DB ?
  84.  ;Information sur la manette de jeu
  85.  JoyExist         DB ?
  86.  BiosJoy          DB ?
  87.  JoyPort          DW ?
  88.  JoyPotentioMeter DW ?
  89.  ;Information sur le clavier
  90.  KbdModel         DB ?
  91.  KbdCtrl          DB ?
  92.  KbdReadPort      DW ?
  93.  BiosKbdEnh       DB ?
  94.  ;Information sur le port parallèle
  95.  LPTExist         DB ? ; Boolean
  96.  NmLPT            DB ?
  97.  Get1LPT          DB ?
  98.  ;Information sur le port série
  99.  ComExist         DB ? ; Boolean
  100.  NmCom            DB ?
  101.  ;Information sur la mémoire conventionnel
  102.  MemTotalSize     DW ?
  103.  ;Information sur l'Expanded Memory Manager (EMS)
  104.  EmmExist         DB ? ; Boolean
  105.  EmmSeg           DW ?
  106.  EmmTotalSize     DW ?
  107.  ;Information sur l'eXtended Memory Manager (XMS)
  108.  XmmExist         DB ? ; Boolean
  109.  XmmCtrl          DD ? ; Pointer
  110.  XmsTotalSize     DW ?
  111.  ;Information sur la mémoire étendu géré par le Bios Int 15h
  112.  ExtBiosExist     DB ? ; Boolean
  113.  ExtBiosSizeK     DW ?
  114.  ;Information sur le CMOS
  115.  CtrlCmos         DB ?
  116.  CmosPort         DW ?
  117.  ;Information sur la souris
  118.  Mouse            DB ?
  119.  MouseVer         DW ?
  120.  MsButton         DW ?
  121.  ; Index de procédures ou fonctions à référence ressource RLL
  122.  indAltPress      DB ? ; AltPressed
  123.  indCtrlPress     DB ? ; CtrlPressed
  124.  indFillChr       DB ? ; FillByte/FillCharacter
  125.  indGetIntVec     DB ? ; GetInterruptVector
  126.  indGetRawTimer   DB ? ; GetRawTimer
  127.  indGetRawTimerB  DB ? ; GetRawTimerInByte
  128.  indJoyPos        DB ? ; JoystickPosition
  129.  indKeyPress      DB ? ; KeyPressed
  130.  indLShiftPress   DB ? ; LeftShiftPressed
  131.  indMove          DB ? ; Move/MoveLeft
  132.  indPushKey       DB ? ; PushKey
  133.  indReadKey       DB ? ; ReadKey
  134.  indRShiftPress   DB ? ; RightShiftPressed
  135.  indSetIntVec     DB ? ; SetInterruptVector
  136.  indShiftPress    DB ? ; ShiftPressed
  137. ENDS
  138.  
  139. ; ***********************************************************************************************
  140. ; Détection de la présence des interruptions et de certains services de base ici ...
  141. ; ***********************************************************************************************
  142.  
  143.    ;-----------------------------------------------------------------------------------------------------------------------------
  144.    ;--                         Détection du CMOS                       
  145.    ;--                (GetCmosPort/CtrlCmos/ExtBiosExist)              
  146.    ;-----------------------------------------------------------------------------------------------------------------------------
  147.   MOV StartUp.StartUpRec.ExtBiosExist,No
  148.   MOV StartUp.StartUpRec.ExtBiosSizeK,0
  149.   TEST Jump.Jumper.FlgMethod,flgProtectedMode
  150.   JNZ nXTCmosTst
  151.   TEST StartUp.StartUpRec.IntExistFlags,flgInt15h
  152.   MOV AX,0FFFFh
  153.   MOV ES,AX
  154.   JZ  @@SetCmosPort ;
  155.   CMP Byte Ptr ES:[0Eh],253
  156.   JA  @@SetCmosPort
  157. nXTCmosTst:
  158.   XOR AX,AX
  159.   TEST Jump.Jumper.FlgMethod,flgNoExtBiosMemDetect
  160.   JNZ nExtInt15
  161.   MOV AH,88h
  162.   INT 15h
  163. nExtInt15:
  164.   OR  AX,AX
  165.   MOV CX,70h
  166.   MOV BL,ctrlCmosMC146818
  167.   JE  @@SetCmosPort ; Pas de Ext Bios Int 15h
  168.   MOV StartUp.StartUpRec.ExtBiosExist,Ya
  169.   MOV StartUp.StartUpRec.ExtBiosSizeK,AX
  170.   JMP @@DetectCmos
  171. @@SetCmosPort:
  172.   MOV AX,0FFFFh
  173.   MOV ES,AX
  174.   CMP Byte Ptr ES:[0Eh],252
  175.   JE  @@DetectCmos
  176.   TEST Jump.Jumper.FlgMethod,flgNoCmosDetect
  177.   JZ @@NoCmos
  178.   CMP Byte Ptr ES:[0Eh],255 ; PC ?
  179.   JE  @@NoCmos
  180.   CMP Byte Ptr ES:[0Eh],253 ; PC Junior ?
  181.   JE  @@NoCmos
  182.   MOV DX,02C0h
  183.   IN  AL,DX
  184.   TEST AL,0Fh
  185.   JNZ @TooBad
  186.   MOV DX,2CBh
  187.   IN  AL,DX
  188.   CMP AL,0DEh
  189.   JE  @CmosB
  190.   MOV AL,0DEh
  191.   OUT DX,AL
  192.   IN  AL,DX
  193.   CMP AL,0DEh
  194.   JE  @CmosB
  195. @TooBad:
  196.   XOR AL,AL
  197.   OUT DX,AL
  198.   INC DX
  199.   IN  AL,DX
  200.   DEC DX
  201.   TEST AL,0Fh
  202.   JNZ @TriBad
  203.   MOV AL,0Bh
  204.   OUT DX,AL
  205.   INC DX
  206.   IN  AL,DX
  207.   CMP AL,0DEh
  208.   JE  @CmosC
  209.   MOV AL,0DEh
  210.   OUT DX,AL
  211.   IN  AL,DX
  212.   CMP AL,0DEh
  213.   JE  @CmosC
  214. @TriBad:
  215.   XOR AL,AL
  216.   OUT DX,AL
  217.   MOV AL,80h
  218.   OUT DX,AL
  219.   MOV BL,0Eh
  220.   INC DX
  221.   MOV AL,BL
  222.   OUT DX,AL
  223.   DEC DX
  224.   MOV AL,88h
  225.   OUT DX,AL
  226.   MOV AL,98h
  227.   OUT DX,AL
  228.   MOV AL,88h
  229.   OUT DX,AL
  230.   MOV AL,80h
  231.   OUT DX,AL
  232.   MOV AL,0A0h
  233.   OUT DX,AL
  234.   INC DX
  235.   MOV CX,100h
  236. @LoopA:
  237.   IN  AL,DX
  238.   TEST AL,1
  239.   LOOPZ @LoopA
  240.   JZ  @NoCmosXT
  241.   MOV CX,100h
  242. @LoopB:
  243.   IN  AL,DX
  244.   TEST AL,1
  245.   LOOPNZ @LoopB
  246.   JZ @CmosA
  247. @NoCmosXT:
  248.   MOV DX,2C0h
  249.   XOR AL,AL
  250.   OUT DX,AL
  251.   ; XT, difficile à dire si un CMOS existe... Wyse, Commodore,...
  252.   ; mais si oui: le Port est E0h pour les ordinateurs Wyses XT
  253.   MOV CX,0E0h
  254.   MOV BL,ctrlCmosUnknown
  255.   JMP nCmosXT
  256. @CmosA:
  257.   MOV BL,ctrlCmosRTC58321 ; RTC-58321, 2C0h-2C1h
  258.   JMP @SetCmosXTPort
  259. @CmosB:
  260.   MOV BL,ctrlCmosMM58167a ; MM58167, 2C0h-2DFh
  261.   JMP @SetCmosXTPort
  262. @CmosC:
  263.   MOV BL,ctrlCmosMM58167b ; MM58167, 2C0h-2C7h
  264. @SetCmosXTPort:
  265.   MOV CX,02C0h
  266. nCmosXT:
  267.   JMP @@DetectCmos
  268. @@NoCmos:
  269.   XOR CX,CX ; Je fixe le port à 0, mais il faudrait
  270.             ; surtout pas essayez pour voir...
  271.   MOV BL,ctrlCmosNo
  272. @@DetectCmos:
  273. ;  LES DI,StartUp
  274.   MOV StartUp.StartUpRec.CmosPort,CX
  275.   MOV StartUp.StartUpRec.CtrlCmos,BL
  276.  
  277.  
  278. ; ***********************************************************************************************
  279. ; Suite des routines détections du démarrage ici...
  280. ; ***********************************************************************************************

Voir également

Basic Pro: Fonction CMOS
Basic Pro: Fonction CMOSEXIST
Basic Pro: Fonction CMOSPORT

Dernière mise à jour : Vendredi, le 4 mars 2016