Section courante

A propos

Section administrative du site

ALLOCATE_LDT_DESCRIPTORS

 Alloue un descripteurs LDT
Free Pascal go32

Syntaxe

Function allocate_ldt_descriptors(count:Word):Word;

Paramètres

Nom Description
count Ce paramètre permet d'indiquer le nombre de descripteurs uniques demandés.

Retour

Valeur Description
entier Ces valeurs permettent d'indiquer un sélecteur de base.

Description

Cette fonction permet d'allouer un certain nombre de descripteurs.

Remarques

Exemple

  1. { Cet exemple démontre l'utilisation des descripteurs et les effets
  2. du changement de leur limite et de leur adresse de base.
  4. Plus en détail, le programme remplit la région décrite par un
  5. descripteur alloué dans la mémoire écran en mode texte avec divers
  6. caractères. Avant de faire cela, il sauvegarde l'intégralité du contenu
  7. de l'écran dans le tas et le restaure ensuite.
  9. Quelques informations supplémentaires :
  11. L'écran texte d'une carte VGA a son espace mémoire à l'adresse $B800:0 ;
  12. la mémoire écran est organisée de manière linéaire, c'est-à-dire que la
  13. deuxième ligne vient directement après la première, où chaque cellule
  14. occupe 2 octets de mémoire (1 octet pour le caractère, 1 octet pour
  15. les attributs). Elle a une taille de 32 Ko.
  17. Ainsi, le décalage d'une seule cellule mémoire par rapport à son origine est :
  19. Y * colonnes * 2 + X * 2
  21. où X et Y désignent le point, et colonnes est le nombre de cellules
  22. caractères par ligne.
  23. }
  24.  
  25. {$mode delphi}
  26.  
  27. Uses
  28.  Crt,go32;
  29.  
  30. Const
  31.   { Dimensions de l'écran en X et Y }
  32.  maxx = 80;
  33.  maxy = 25;
  34.   { Nombre d'octets utilisés pour chaque cellule de caractères }
  35.  bytespercell = 2;
  36.   { Taille de l'écran en octets }
  37.  screensize = maxx * maxy * bytespercell;
  38.  
  39.   { Adresse linéaire de $B800:0 }
  40.  linB8000 = $B800 * 16;
  41.  
  42. Type
  43.  string80 = string[80];
  44.  
  45. Var
  46.   { Contient l'ancien contenu de l'écran }
  47.  Text_Save:Array[0..screensize-1] of Byte;
  48.   { Anciennes coordonnées du curseur X et Y }
  49.  Text_oldx,Text_oldy:Word;
  50.  
  51.   { Sélecteur vers l'écran en mode texte }
  52.  Text_sel:Word;
  53.  
  54.  { Affiche un message d'état sur la première ligne de l'écran puis attend une pression de touche }
  55. Procedure status(s : string80);Begin
  56.  GotoXY(1, 1);
  57.  ClrEol;
  58.  Write(s);
  59.  ReadKey;
  60. End;
  61.  
  62.  { Affiche des informations sur le descripteur sur les 2 dernières lignes }
  63. Procedure selinfo(sel:Word);Begin
  64.  GotoXY(1, 24);
  65.  ClrEol;
  66.  WriteLn('Adresse de base du descripteur : $',hexstr(get_segment_base_address(sel), 8));
  67.  ClrEol;
  68.  Write('Limite du descripteur : ',get_segment_limit(sel));
  69. End;
  70.  
  71.  { Retourne une cellule de caractère de 2 octets, incluant les données du caractère et ses attributs de couleur }
  72. Function makechar(ch:char;color:byte):Word;Begin
  73.  makechar:=byte(ch) or (color shl 8);
  74. End;
  75.  
  76. BEGIN
  77.   { Sauvegarde le contenu original de l'écran dans une variable, cette fois en utilisant seg_move() et la variable dosmemselector }
  78.  seg_move(dosmemselector, linB8000, get_ds, longint(@text_save),screensize);
  79.   { Nous devons également sauvegarder les anciennes coordonnées du curseur sur l'écran }
  80.  text_oldx := WhereX; 
  81.  text_oldy := WhereY;
  82.   { Efface entièrement l'écran }
  83.  seg_fillword(dosmemselector, linB8000, screensize div 2,
  84.  makechar(' ', Black or (Black shl 4)));
  85.   { Affiche un message }
  86.  status('Création du sélecteur ''text_sel'' pour une partie de la mémoire écran en mode texte');
  87.   { Alloue un descripteur }
  88.  text_sel := allocate_ldt_descriptors(1);
  89.   { Définit son adresse de base à l'adresse linéaire de l'écran texte la taille en octets d'une ligne (=maxx * bytespercell * 1) }
  90.  set_segment_base_address(text_sel,linB8000 + bytespercell * maxx * 1);
  91.   { Définit la limite à la taille de l'écran réduite d'un octet (obligatoire) et du nombre de lignes à ne pas modifier (première ligne + les 2 dernières lignes) }
  92.  set_segment_limit(text_sel, screensize - 1 - bytespercell *  maxx * 3);
  93.   { Affiche les informations du descripteur }
  94.  selinfo(text_sel);
  95.  status('et effacement de toute la mémoire sélectionnée par le descripteur ''text_sel''');
  96.   { Remplit toute la mémoire sélectionnée avec des caractères uniques }
  97.  seg_fillword(text_sel, 0, (get_segment_limit(text_sel)+1) div 2,makechar(' ', LightBlue shl 4));
  98.  status('Remarquez que seule la mémoire décrite par le descripteur a changé, rien d''autre');
  99.  status('Réduction maintenant de sa limite et de sa base, et définition de sa mémoire décrite');
  100.   { Modifie l'adresse de base du descripteur (l'augmente de la taille en octets d'une ligne) }
  101.  set_segment_base_address(text_sel,get_segment_base_address(text_sel) + bytespercell * maxx);
  102.   { Réduit la limite de la taille en octets de 2 lignes (1 ligne car l'adresse de base a changé, une autre ligne en bas) }
  103.   set_segment_limit(text_sel,get_segment_limit(text_sel) - bytespercell * maxx * 2);
  104.   { Affiche les informations du descripteur }
  105.  selinfo(text_sel);
  106.  status('Remarquez que l''adresse de base a augmenté d''une ligne mais que la limite a diminué de 2 lignes');
  107.  status('Cela devrait vous donner un indice sur le fait que la limite est relative à la base');
  108.  { Remplit la zone du descripteur }
  109.  seg_fillword(text_sel, 0, (get_segment_limit(text_sel)+1) div 2,makechar(#176, LightMagenta or Brown shl 4));
  110.  status('Maintenant, faisons quelque chose de plus fou : ' +
  111.         'copier 10 lignes de données de l''écran précédemment sauvegardé');
  112.   { Copie la mémoire du segment de données vers l'écran }
  113.  seg_move(get_ds, longint(@text_save), text_sel,maxx * bytespercell * 2, maxx * bytespercell * 10);
  114.  status('Enfin, libération du descripteur et restauration du contenu de l''écran...');
  115.  status('J''espère que ce petit programme vous donnera des ' +
  116.          'indices sur la manipulation des descripteurs');
  117.   { Libère le descripteur pour qu'il puisse être utilisé pour autre chose }
  118.  free_ldt_descriptor(text_sel);
  119.   { Restaure l'état précédent }
  120.  seg_move(get_ds, longint(@text_save), dosmemselector,linB8000, screensize);
  121.  GotoXY(text_oldx, text_oldy);
  122. END.
  123.  

Dernière mise à jour : Dimanche, le 23 Août 2020