Il est très agaçant d'avoir des formules toutes préparés d'avance fonctionnant très bien dans des tableurs et ne pas être capable d'effectuer les mêmes calculs et les mêmes réponses dans une situation anodine de la programmation. Une de ces remarquables fonctions, est celle du Lotus 1-2-3 et de Quattro Pro, elle se nomme la fonction PPaymt en anglais ou Principal en français. A l'aide du code source QuickBASIC/QBasic suivant, vous trouverez la réponse que vous souhaitez :
- DECLARE FUNCTION FVal! (rate!, nPer!, pmt!, pV!, pType!)
- DECLARE FUNCTION Paymt! (rate!, nPer!, pV!, fV!, pType!)
- DECLARE FUNCTION PPaymt! (rate!, per!, nPer!, pV!, fV!, pType!)
-
- PRINT "Exemple de versements trimestriels d'un prêt de 10 000$ à 15% par trimestre:"
- PRINT STR$(PPaymt(.15 / 4, 24, 40, 10000, 0, 1)) + "$"
- PRINT "Exemple de versements d'un prêt de 100 000$ à 10% par mois:"
- PRINT STR$(PPaymt(.1 / 12, 2 * 12, 30 * 12, 100000, 0, 0)) + "$"
-
- FUNCTION FVal (rate, nPer, pmt, pV, pType)
- f = EXP(nPer * LOG(1! + rate))
- IF ABS(rate) < .000001 THEN
- FVal = -pmt * nPer * (1! + (nPer - 1!) * rate / 2!) * (1! + rate * pType) - pV * f
- ELSE
- FVal = pmt * (1 - f) * (1 / rate + pType) - pV * f
- END IF
- END FUNCTION
-
- FUNCTION Paymt (rate, nPer, pV, fV, pType)
- f = EXP(nPer * LOG(1! + rate))
- Paymt = (fV + pV * f) * rate / ((1 + rate * pType) * (1! - f))
- END FUNCTION
-
- FUNCTION PPaymt (rate, per, nPer, pV, fV, pType)
- f = Paymt(rate, nPer, pV, fV, pType)
- PPaymt = f - rate * FVal(rate, per - pType - 1, f, pV, pType)
- END FUNCTION
on obtiendra le résultat suivant :
Exemple de versements trimestriels d'un prêt de 10 000$ à 15% par trimestre:-233.243
Exemple de versements d'un prêt de 100 000$ à 10% par mois:
-53.542
Dernière mise à jour : Mercredi, le 14 septembre 2016